PiercingPattern

Description

The Piercing Pattern is a two candlestick, bullish reversal pattern. The previous candlestick has a long, black real body. The current candlestick opens below the previous candlestick's low (gaps down) but ascends to a level near, but below, the previous candlesticks's real body high. (Note: were the current candlestick to ascend above the previous candlestick's real body high, a bullish Engulfing Pattern would emerge.)

While the current candlestick's real body high is less than the previous candlestick's real body high, The Piercing Pattern exists. The greater the penetration into the previous bar's real body, the stronger the pattern.

Some analysts do not consider a piercing pattern valid unless the current real body high ascends above the previous candlestick's real body mid-point.

The Piercing Pattern's companion pattern is the Dark Cloud Cover.

Formula

PiercingPattern(INPUT, Stringency=6, LRRange=10, LRType=3, DojiPercentage=10)=begin

retval = NONUM

  targetBar = 0

  cOpen = GetPrice($1, BATE_OPEN, targetBar, 0)

  cClose = GetPrice($1, BATE_CLOSE, targetBar, 0)

  cLow = GetPrice($1, BATE_LOW, targetBar, 0)

  pOpen = GetPrice($1, BATE_OPEN, (targetBar + 1), 0)

  pClose = GetPrice($1, BATE_CLOSE, (targetBar + 1), 0)

  pHigh = GetPrice($1, BATE_HIGH, (targetBar + 1), 0)

  pLow = GetPrice($1, BATE_LOW, (targetBar + 1), 0)

  pMid = RealBodyMidPoint($1, (targetBar+1))

  if WhiteBody($1, targetBar) == TRUE then begin

    if BlackBody($1,(targetBar + 1)) == TRUE OR DojiForm($1, (targetBar + 1), DojiPercentage) OR LongBlackForm($1, (targetBar + 1)) == TRUE then begin

      if cOpen <= pClose And cClose <= pOpen And cClose > pClose then begin

        if Stringency >= 6 then retval = '6'|clr_green|ftiny|below|arrow|vertical

        if cOpen <= pLow then begin

          if Stringency >= 5 then retval = '5'|clr_green|ftiny|below|arrow|vertical

          if Bearish($1, targetBar) == TRUE then begin

            if Stringency >= 4 then retval = '4'|clr_green|ftiny|below|arrow|vertical

            if NewLow($1, targetBar) == TRUE then begin

              if Stringency >= 3 then retval = '3'|clr_green|ftiny|below|arrow|vertical

              if cClose >= pMid then begin

                if Stringency >= 2 then retval = '2'|clr_green|ftiny|below|arrow|vertical

                if cClose < pOpen then begin

                  retval = 'PIERCING'|clr_black|ftiny|below|arrow|vertical

                end

              end

            end

          end

        end

      end

    end

  end

  retval

end

Parameters

INPUT

The INPUT directive makes this formula available as a Formula Overlay. INPUT refers to the instrument in the chart.

Stringency

The Stringency argument is used by nearly all candlestick overlays. It controls how many tests must pass in the evaluation of a Piercing Pattern. The lower the number, the more strict the interpretation.

The Stringency argument is an overlay parameter. You can adjust it using the Parameters dialog. The default is 6.

LRRange

The PiercingPattern overlay uses the LR() function with either a continuous or quadratic calculation to determine how the market is trending. The LRRange (Linear Regression Range) parameter is the number of points in the Linear Regression calculation. The default is 10.

LRType

The LRType parameter has two possible settings: 2 and 3, or continuous linear regression and quadratic linear regression, respectively. The default is 3, or quadratic.

DojiPercentage

The DojiPercentage parameter represents a percentage. This parameter serves as the basis for determining whether a candlestick is Doji or near Doji. The smaller the value assigned to DojiPercentage the more stringent the test. The default is 10, or ten percent.

Return Value

The return value is a string plot and varies depending on the value of the Stringency parameter.  The lower the number, the stronger the pattern.

Bullish indicators are rendered in green below the candlestick.

The string plot for a fully qualified Inverted Piercing Pattern is "Piercing" rendered in black below the candlestick.

Examples

Comments

NA