Engulfing

Description

The Engulfing pattern is a two-candlestick reversal pattern. An engulfing pattern may be bullish or bearish. A bullish engulfing pattern is a black bodied candlestick "engulfed" by a white bodied candlestick:

By contrast, a bearish engulfing pattern is a white bodied candlestick engulfed by a black bodied candlestick:

To engulf, the current candlestick's color must not match the previous candlestick. If this threshold criteria is true, the current candlestick's real body high and low must be greater than and less than the previous candlestick's real body high and low, respectively.

The Engulfing pattern is similar to the Western Reversal Day pattern in bar charts.

Factors that increase the Engulfing pattern significance include the following:

1. Radical difference in real body size indicates increased reversal force.

2. An Engulfing pattern in a sustained trend increases the probability that buyers are long, or that sellers are short.

3. Heavy volume on the Engulfing day may indicate profit taking in an up trend, or a bottom in a down trend.

4. A long pattern that engulfs more than one opposite colored candlesticks is regarded as significant.

Formula

Engulfing(INPUT, Stringency=7, LRRange=10, LRType=3)=begin

  retval = NONUM

  targetBar = 0

  cOpen = GetPrice($1, BATE_OPEN, targetBar, 0)

  cHigh = GetPrice($1, BATE_HIGH, targetBar, 0)

  cClose = GetPrice($1, BATE_CLOSE, targetBar, 0)

  cLow = GetPrice($1, BATE_LOW, targetBar, 0)

  cVol = GetVolume($1, targetBar)

  pOpen = GetPrice($1, BATE_OPEN, (targetBar + 1), 0)

  pClose = GetPrice($1, BATE_CLOSE, (targetBar + 1), 0)

  pHigh = GetPrice($1, BATE_HIGH, (targetBar + 1), 0)

  pLow = GetPrice($1, BATE_LOW, (targetBar + 1), 0)

  pVol = GetVolume($1, (targetBar + 1))

  if BlackBody($1, targetBar) == TRUE AND WhiteBody($1,(targetBar + 1)) == TRUE then begin

    if cOpen > pClose And cClose < pOpen then begin

      if Stringency >= 7 then retval = '7'|clr_red|above|ftiny|arrow|vertical

      if LongBlackForm($1, targetBar) == TRUE then begin

        if Stringency >= 6 then retval = '6'|clr_red|above|ftiny|arrow|vertical

        if cOpen >= pHigh And cClose <= pLow then begin

          if Stringency >= 5 then retval = '5'|clr_red|above|ftiny|arrow|vertical

          if Bullish($1, targetBar, LRRange, LRType) == TRUE then begin

            if Stringency >= 4 then retval = '4'|clr_red|above|ftiny|arrow|vertical

            if NewHigh($1, targetBar) == TRUE then begin

              if Stringency >= 3 then retval = '3'|clr_red|above|ftiny|arrow|vertical

              if DojiForm($1,(targetBar + 1)) == TRUE then begin

                if Stringency >= 2 then retval = '2'|clr_red|above|ftiny|arrow|vertical

                if cVol > pVol then begin

                  retval = 'Engulfing'|clr_black|above|ftiny|arrow|vertical

                end

              end

            end

          end

        end

      end

    end

  end

  if WhiteBody($1, targetBar) AND BlackBody($1, (targetBar + 1)) then begin

    if RealBodyHigh($1, targetBar) > RealBodyHigh($1, (targetBar + 1)) AND RealBodyLow($1, targetBar) < RealBodyLow($1, (targetBar + 1)) then begin

      if Stringency >= 7 then retval = '7'|clr_green|below|ftiny|arrow|vertical

      if LongWhiteForm($1, targetBar) == TRUE then begin

        if Stringency >= 6 then retval = '6'|clr_green|below|ftiny|arrow|vertical

        if cOpen <= pLow And cClose >= pHigh then begin

          if Stringency >= 5 then retval = '5'|clr_green|below|ftiny|arrow|vertical

          if Bearish($1, targetBar, LRRange, LRType) == TRUE then begin

            if Stringency >= 4 then retval = '4'|clr_green|below|ftiny|arrow|vertical

            if NewLow($1, targetBar) == TRUE then begin

              if Stringency >= 3 then retval = '3'|clr_green|below|ftiny|arrow|vertical

              if DojiForm($1, (targetBar + 1)) == TRUE then begin

                if Stringency >= 2 then retval = '2'|clr_green|below|ftiny|arrow|vertical

                if cVol > pVol then begin

                  retval = 'ENGULFING'|clr_black|below|ftiny|arrow|vertical

                end

              end

            end

          end

        end

      end

    end

  end

  retval

end

Parameters

INPUT

The INPUT directive makes this formula available as a Formula Overlay. INPUT refers to the instrument in the chart.

Stringency

The Stringency argument is used by nearly all candlestick overlays. It controls how many tests must pass in the evaluation of an Engulfing pattern. The lower the number, the more strict the interpretation.

The Stringency argument is an overlay parameter. You can adjust it using the Parameters dialog. The default is 7.

LRRange

The Engulfing overlay uses the LR() function with either a continuous or quadratic calculation to determine how the market is trending. The LRRange (Linear Regression Range) parameter is the number of points in the Linear Regression calculation. The default is 10.

LRType

The LRType parameter has two possible settings: 2 and 3, or continuous linear regression and quadratic linear regression, respectively. The default is 3, or quadratic.

Return Value

The return value is a string plot and varies depending on the value of the Stringency parameter.  The lower the number, the stronger the pattern.

Bearish indicators are rendered in red above the candlestick. Bullish indicators are rendered in green below the candlestick.

The string plot for a fully qualified Engulfing pattern is "Engulfing" rendered in black above (bearish) or below (bullish) the candlestick.

Examples

Comments

NA