TwoCrows

Description

The Two Crows, or Upside Gap Two Crows, is a bearish pattern. There are three bars in this pattern:

The two black bars gap above the white candlestick's close. Ideally, the second black body opens above and closes below the first black candlestick.

Formula

TwoCrows(INPUT,Stringency=3,LRRange=10,LRType=3,Deviation=.10)=begin

  retval = NONUM

  targetBar = 0

  pnt1 = targetBar

  pnt2 = targetBar + 1

  pnt3 = targetBar + 2

  cBase = GetPrice($1, BATE_CLOSE, pnt3, 0)

  pClose = GetPrice($1, BATE_CLOSE, pnt2, 0)

  pOpen = GetPrice($1, BATE_OPEN, pnt2, 0)

  cClose = GetPrice($1, BATE_CLOSE, pnt1, 0)

  cOpen = GetPrice($1, BATE_OPEN, pnt1, 0)

  thisDev = DevRange($1, pnt1, 2)

  if WhiteBody($1, pnt3) then begin

    if BlackBody($1, pnt2) AND BlackBody($1, pnt1) then begin

      if pClose > cBase AND cClose > cBase then begin

        if Stringency >= 4 then retval = '4'|clr_red|arrow|above|vertical|ftiny

        if cOpen > pClose and cClose < pClose then begin

          if Stringency >= 3 then retval = '3'|clr_red|arrow|above|vertical|ftiny

          if Bullish($1, pnt3, LRRange, LRType) then begin

            if Stringency >= 2 then retval = '2'|clr_red|arrow|above|vertical|ftiny

            if thisDev < Deviation then begin

              retval = 'TWO CROWS'|clr_black|arrow|above|vertical|ftiny

            end

          end

        end

      end

    end

  end

  retval

end

Parameters

INPUT

The INPUT directive makes this formula available as a Formula Overlay. INPUT refers to the instrument in the chart.

Stringency

The Stringency argument is used by nearly all candlestick overlays. It controls how many tests must pass in the evaluation of Two Crows. The lower the number, the more strict the interpretation.

The Stringency argument is an overlay parameter. You can adjust it using the Parameters dialog. The default is 3.

LRRange

The TwoCrows overlay uses the LR() function with either a continuous or quadratic calculation to determine how the market is trending. The LRRange (Linear Regression Range) parameter is the number of points in the Linear Regression calculation. The default is 10.

LRType

The LRType parameter has two possible settings: 2 and 3, or continuous linear regression and quadratic linear regression, respectively. The default is 3, or quadratic.

Deviation

The Deviation parameter sets a deviation between the two black real bodies of this pattern. The formula calculates a standard deviation of real body length. If the standard deviation is less than the CandleDeviation parameter, the pattern is valid. The default is 0.10.

Return Value

The return value is a string plot and varies depending on the value of the Stringency parameter.  The lower the number, the stronger the pattern.

Bearish indicators are rendered in red above the candlestick.

The string plot for a fully qualified Two Crows is "Two Crows" rendered in black above the candlestick.

Examples

Comments

NA