RisingThree

Description

The Rising Three pattern is similar to the Western Pennant formation and is generally thought of as a resting market.

The Rising Three pattern is a bullish continuation pattern, so bullish trend identification is important.

This Pattern is a five-candlestick pattern:

The first and fifth candles are white and surround three black candlesticks. Further, the three black candlesticks trade within the range of the fifth candlestick back.

The Falling Three pattern is the opposite of this pattern.

Formula

RisingThree(INPUT, LRRange=10, LRType=3, LongCandle=2)=begin

  retval = NONUM

  targetBar = 0

  pnt1 = targetBar

  pnt2 = targetBar + 1

  pnt3 = targetBar + 2

  pnt4 = targetBar + 3

  baseHigh = GetPrice($1, BATE_HIGH, pnt4, 0)

  baseLow = GetPrice($1, BATE_LOW, pnt4, 0)

  ppHigh = GetPrice($1, BATE_HIGH, pnt3, 0)

  ppLow = GetPrice($1, BATE_LOW, pnt3, 0)

  ppOpen = GetPrice($1, BATE_OPEN, pnt3, 0)

  pHigh = GetPrice($1, BATE_HIGH, pnt2, 0)

  pLow = GetPrice($1, BATE_LOW, pnt2, 0)

  pOpen = GetPrice($1, BATE_OPEN, pnt2, 0)

  cHigh = GetPrice($1, BATE_HIGH, pnt1, 0)

  cLow = GetPrice($1, BATE_LOW, pnt1, 0)

  cOpen = GetPrice($1, BATE_OPEN, pnt1, 0)

  if WhiteBody($1, pnt4) AND LongForm($1, pnt4, LongCandle) AND Bullish($1, pnt3, LRRange, LRType) then begin

    if BlackBody($1, pnt3) AND BlackBody($1, pnt2) and BlackBody($1, pnt1) then begin

      if cHigh <= baseHigh AND pHigh <= baseHigh AND ppHigh <= baseHigh then begin

        if cLow >= baseLow AND pLow>= baseLow AND ppLow >= baseLow then begin

          retval = 'Rising Three'|clr_green|arrow|below|vertical|ftiny

        end

      end

    end

  end

  if WhiteBody($1, pnt3) AND LongForm($1, pnt3, LongCandle) AND Bullish($1, pnt3, LRRange, LRType) then begin

    if BlackBody($1, pnt2) and BlackBody($1, pnt1) then begin

      baseHigh = GetPrice($1, BATE_HIGH, pnt3, 0)

      baseLow = GetPrice($1, BATE_LOW, pnt3, 0)

      if cHigh <= baseHigh AND pHigh <= baseHigh then begin

        if cLow >= baseLow AND pLow>= baseLow then begin

          retval = 'Rising Two'|clr_green|arrow|below|vertical|ftiny

        end

      end

    end

  end

  retval

end

Parameters

INPUT

The INPUT directive makes this formula available as a Formula Overlay. INPUT refers to the instrument in the chart.

LRRange

This overlay uses the LR() function with either a continuous or quadratic calculation to determine how the market is trending. The LRRange (Linear Regression Range) parameter is the number of points in the Linear Regression calculation. The default is 10.

LRType

The LRType parameter has two possible settings: 2 and 3, or continuous linear regression and quadratic linear regression, respectively. The default is 3, or quadratic.

LongCandle

The LongCandle parameter is a percentage used to validate a long real body. If the move from open to close exceeds the percentage in this parameter, a candlestick has a long real body. The default is 2, or two percent.

Return Value

The string plot for a fully qualified Rising Three pattern is "Rising Three" rendered in green below the candlestick. This overlay may also detect a Rising Two pattern, which is rendered "Rising Two" in green below the candlestick.

Examples

Comments

NA